Dot Tunnel

It just had to be time for a quick break with my running Amiga 4000. The below code in AMOS will generate a tunnel with dots rotating in AMOS in 50fps.

How was this possible, AMOS is sooo slow? Easy, the same old trick as “unlimited bobs”.

Have fun! ­čÖé

 

The code

' ************************************
'            Dot Tunnel v0.1
' ************************************

Auto View Off
Hide 

For S=0 To 7
   Screen Open S,320,256,2,Lowres
   Curs Off : Flash Off : Cls 0
   Palette $0,$EEE
   Screen Hide S
Next S

Degree

_XORIGO=Screen Width/2
_YORIGO=Screen Height/2
_RADIUS=180
_VIEW=0
_DISTOFF=0
_DISTADD=-6

For A=0 To 7

   Screen A
   _ZDIST=1100+_DISTOFF
   _DISTOFF=_DISTOFF+_DISTADD
   _DEGOFF=0

   For Z=0 To 25

      _DEG=A+_DEGOFF
      Add _DEGOFF,1
      For R=0 To 44

         X=Sin(_DEG)*_RADIUS
         Y=Cos(_DEG)*_RADIUS
         Rol.l 8,X
         Rol.l 8,Y
         _XP=X/_ZDIST
         _YP=Y/_ZDIST
         Plot _XORIGO+_XP,_YORIGO+_YP
         Add _DEG,8

      Next R

      _ZDIST=_ZDIST-48

   Next Z

Next A

Auto View On 

Repeat 

   Wait Vbl
   Screen Hide _VIEW
   Add _VIEW,1,0 To 7
   Screen Show _VIEW

Until Mouse Key
End